Menghosting ghost

Ghost adalah platform blogging modern yang powerful, artikel ini akan membahas cara mempublikasikan Ghost ke jaringan sebagai situs statis.

Untuk mempublikasikan Ghost kita perlu server sebagai penyimpanan online. sama halnya seperti wordpress yang dijalankan melalui server, untuk menggunakan server tentu saja kita harus mengeluarkan uang tapi ada juga layanan yang tidak berbayar, ingin tahu lebih lanjut? simak artikel ini

tempat hosting ghost

ada dua jenis tempat hosting cms ghost :

1. versi berbayar
2. versi gratis

1 Versi berbayar

Keuntungan versi berbayar anda tidak perlu repot menyentuh terminal untuk menginstall ghost. sehingga anda bisa fokus untuk menulis kontent, tanpa harus menangani hal teknis.

Jika anda ingin menggunakan ghost versi berbayar yang siap pakai, saya sarankan layanan:

1. Ghost pro - dari official ghost
2. Digital Press

sebelumnya digitalpress menyediakan penyimpanan ghost gratis, namun sekarang berbayar seharga 1 euro atau sama dengan 30 ribu rupiah per bulan nya, ini tergolong ==sangat murah== ketimbang anda harus menghabiskan waktu untuk mengotak-atik komputer anda

2 Versi gratis

Namun jika anda ingin tempat penyimpanan ghost gratis, berikut panduannya.

Bagaimana konsepnya?

kita akan mengkoversi ghost menjadi versi statis yang kemudian disebarkan kejaringan edge seperti cloudlfare , vercel, netlify atau github.

Konversi ghost menjadi statis

Sebelum itu saya asumsikan ==anda sudah berhasil menjalankan Ghost secara lokal di komputer==.

jika belum,

baca artikel ini bagaimana cara menginstall ghost Instalasi Ghost di Windows 11

1. buka cmd, jalankan ghost anda :

   ghost start
   

   maka ghost di buka di

   • http://localhost:2368/ namun disini saya menggantinya menjadi :
   • http://ghost.local:2368/, apa alasannya? baca artikel ini diatas untuk memahaminya

2. lalu buka text editor, salin kode ini kedalamnya dan beri nama upload.bat kemudian tekan enter :

   @echo off
   :: ┌────────────────────────────────────────────────────────────────────┐
   :: │ 🚀 Export Situs Ghost Lokal ke HTML Statis (termasuk sitemap)     │
   :: └────────────────────────────────────────────────────────────────────┘
   
   :: 📍 Ambil folder dan nama file .bat
   set "BAT_DIR=%~dp0"
   set "BAT_NAME=%~n0"
   set "OUTPUT=%BAT_DIR%%BAT_NAME%"
   set "URL=http://ghost.local:2368"
   
   echo.
   echo 📂 Menyimpan hasil di: %OUTPUT%
   
   :: 🧹 Hapus folder output lama jika ada
   if exist "%OUTPUT%" (
       rmdir /s /q "%OUTPUT%"
       echo     ✅ Folder lama dihapus.
   ) else (
       echo     ℹ️ Folder belum ada, lanjut membuat baru.
   )
   mkdir "%OUTPUT%"
   
   :: 🌐 Mulai crawling Ghost + sitemap lengkap
   echo.
   echo 🌐 Tahap 1: Crawling seluruh situs Ghost dan sitemap...
   
   wget ^
       --recursive ^
       --convert-links ^
       --adjust-extension ^
       --page-requisites ^
       --no-parent ^
       --no-host-directories ^
       --cut-dirs=0 ^
       --execute robots=off ^
       --directory-prefix="%OUTPUT%" ^
       %URL% ^
       %URL%/sitemap.xml ^
       %URL%/sitemap-posts.xml ^
       %URL%/sitemap-pages.xml ^
       %URL%/sitemap-tags.xml ^
       %URL%/sitemap-authors.xml ^
       %URL%/sitemap.xsl
   
   :: 🛠 Perbaiki href XSL di sitemap.xml agar bisa dibuka secara lokal
   echo.
   echo 🛠 Tahap 2: Memperbaiki referensi XSL...
   
   for %%F in ("%OUTPUT%\sitemap.xml") do (
       powershell -Command "(Get-Content -Raw '%%F') -replace 'href=\".*sitemap.xsl\"', 'href=\"sitemap.xsl\"' | Set-Content -Encoding UTF8 '%%F'"
   )
   
   :: ✅ Selesai!
   echo.
   echo ✅ Crawling dan modifikasi selesai!
   echo     ➜ Buka file berikut untuk uji lokal:
   echo     %OUTPUT%\index.html
   echo     %OUTPUT%\sitemap.xml
   pause
   

   yang perlu perhatikan pada kode diatas adalah pada bagian ini :

   • set"OUTPUT=%BAT_DIR%%BAT_NAME%" fungsinya yaitu membuat folder secara otomatis, jika anda beri nama file .bat dengan nama upload.bat maka foldernya adalah upload
   • set "URL=http://ghost.local:2368" sesuaikan urlnya dengan url ghost milik anda,

fungsi script diatas adalah untuk mengubah ghost anda menjadi statis html

setelah kode dijalankan maka kode tersebut akan mengkonversi ghost menjadi statis html. terletak pada folder output atau yang sudah anda tentukan sebelumnya.

dari sini anda sudah memiliki statis html inilah yang akan di upload ke jaringan edge

jadi, setiap kali anda ingin memperbaharui artikel maka anda harus menjalankan kode itu setiap kalinya, kemudian mengupload ulang